SPSS

1 When to use SPSS

We use R for almost all data analysis. However, R is code-based and has a steep learning curve. As a result, undergraduate students in the lab most often use SPSS or jamovi for their research projects (e.g., Honors projects and SROP projects), because SPSS and jamovi have a point-and-click interface.

2 Creating a SPSS Syntax File to Import a .csv Data File

A .csv file is a “comma-separated values” file—a file whose values are separated by commas. The lab will provide you with a .csv in your member user folder. You will then need to create a SPSS syntax file to import and save the data into SPSS format. This data file imports the data and only needs to be run when there’s a new data set.

1. Open SPSS in the search bar
2. Go to file, import data, select .csv data
3. Navigate to the desired .csv file
4. Select data file and select paste
5. Once the data preview opens, select paste again
6. A SPSS syntax file will open, select save as and move the file to the desired location
   • save file as: import.sps
7. Open the syntax file and make sure lab path is saved as the absolute file path in the (/FILE=) field (not a mapped network drive like R:)
   • \\lc-rs-store24.hpc.uiowa.edu\lss_itpetersen\Lab\Members\HAWKID\Thesis\Data\srs_idWave.csv
8. To run your script, select CTRL A and press the green play button to run the script
9. In the import script, SPSS will automatically determine the type of variable each should be, but it does not always classify them correctly.
   • For numeric variables used in analysis, use the following command to change the variable to numeric
   • e.g., (tcid AUTO) to (tcid F4.2)
10. At this point, the data file should appear. Next, save the data in SPSS format (.sav) with the below steps:
    • On the open data file, select save as and paste
    • This will copy and paste the syntax at the end of the syntax file in the import script. The completed import script will now read the .csv file and convert it to an SPSS data file (.sav).
    • At this point, you can proceed here to start your analysis script!

Example:

GET DATA  /TYPE=TXT
  /FILE="\\lc-rs-store24.hpc.uiowa.edu\lss_itpetersen\Lab\Members\HAWKID\Thesis\Data\srs_idWave.csv"
  /ENCODING='UTF8'
  /DELIMITERS=","
  /QUALIFIER='"'
  /ARRANGEMENT=DELIMITED
  /FIRSTCASE=2
  /DATATYPEMIN PERCENTAGE=95.0
  /VARIABLES=
  tcid AUTO
  wave AUTO
  tc_sex AUTO
  tc_ageLV1 F4.2
  /MAP.
RESTORE.
CACHE.
EXECUTE.

SAVE OUTFILE='\\lc-rs-store24.hpc.uiowa.edu\lss_itpetersen\Lab\Members\HAWKID\Thesis\Data\srs_idWave.sav'
  /COMPRESSED.

3 Data Management

Add any data management/transformations at the end of your import.sps file (after importing your data), so you re-run the transformations each time you update the data file.

3.1 Average Across Variables

COMPUTE cbcl_externalizingPOM_Average = MEAN(cbcl_externalizingPOM_Father,cbcl_externalizingPOM_Mother,cbcl_externalizingPOM_Secondary).
COMPUTE cbq_inhibitoryControl_Average = MEAN(cbq_inhibitoryControl_Father,cbq_inhibitoryControl_Mother,cbq_inhibitoryControl_Secondary).
EXECUTE.

3.2 Rename Variables

RENAME VARIABLES (ses_hollingsheadSES = SES).

3.3 Mean-Center Variables

COMPUTE ses_hollingsheadSES_mc = ses_hollingsheadSES - mean_ses.
COMPUTE adi_nationalRank_mc = adi_nationalRank - mean_adiN.
EXECUTE.

3.4 Compute Interaction Terms

COMPUTE ses_adi_interaction =  ses_hollingsheadSES_mc * adi_nationalRank_mc.
EXECUTE.

3.5 Save Data File

SAVE OUTFILE='\\lc-rs-store24.hpc.uiowa.edu\lss_itpetersen\Lab\Members\HAWKID\Thesis\Data\srs_idWave.sav'
  /COMPRESSED.

4 Creating a SPSS Syntax File for Analysis

1. To create a new syntax file, select file then new then syntax
   • Save file as: descriptives.sps
2. In your syntax file, create comments for your different types of analyses.
   • e.g., frequencies, descriptives, correlations
3. In your new data file, select an analysis and choose paste. In your despriptives syntax file, the analysis should now be added. For each subsequent analysis, select paste to add it to the descriptives file under the appropriate syntax.
4. Create a new SPSS syntax file for your analysis. In this syntax file, add your analysis
   • e.g., regressions

4.1 Frequencies

FREQUENCIES VARIABLES=tc_sex tc_hispanic tc_race tc_ethnicity 
  /ORDER=ANALYSIS.

4.2 Descriptives

DESCRIPTIVES VARIABLES=ICsim IClim IChg ICcbq ses_hollingsheadSES ADINat EXTBx 
  /STATISTICS=MEAN STDDEV MIN MAX KURTOSIS SKEWNESS.

4.3 Histograms

GRAPH
  /HISTOGRAM=ses_hollingsheadSES.

4.4 Correlations

CORRELATIONS
  /VARIABLES=tc_ageLV1 ses_hollingsheadParent cbq_inhibitoryControl_Average 
    lim_scoreExcludingPreferencePOM hg_scorePOM sim_goXnoGoPOM cbcl_externalizingPOM_Average
  /PRINT=TWOTAIL NOSIG FULL
  /MISSING=PAIRWISE.

4.5 Multiple Regression

REGRESSION
/MISSING PAIRWISE
/STATISTICS COEFF OUTS R ANOVA
/CRITERIA=PIN(.05) POUT(.10)
/NOORIGIN 
/DEPENDENT outcome
/METHOD=ENTER predictor1 predictor2 predictor3.

4.6 Mediation

First, download and run the PROCESS macro.

Below is the syntax for a model without covariates—replace outcome with name of outcome variable, predictor with name of predictor variable, and mediator with name of mediating variable:

PROCESS 
  y=outcome
  /x=predictor
  /m=mediator1 mediator2 mediator3
  /model=4
  /total=1
  /effsize=1
  /stand=1
  /boot=10000
  .

Model with covariates (p. 126):

PROCESS 
  y=outcome
  /x=predictor
  /m=mediator1 mediator2 mediator3
  /cov=covariate1 covariate2 covariate3
  /model=4
  /total=1
  /effsize=1
  /stand=1
  /boot=10000
  .

4.7 Moderation

1. Calculate means of the predictor and moderator

   aggregate outfile * mode addvariables
   /predictor_mean = mean(predictor).
   
   aggregate outfile * mode addvariables
   /moderator_mean = mean(moderator).

2. Mean-center the predictor and moderator

   compute predictor_MC = predictor - predictor_mean.
   compute moderator_MC = moderator - moderator_mean.
   execute.

3. Verify that predictor and moderator are mean-centered (i.e., have a mean of zero)

   DESCRIPTIVES VARIABLES=predictor moderator predictor_MC moderator_MC
   /STATISTICS=MEAN STDDEV MIN MAX.

4. Create the interaction terms

   compute predictorXmoderator = predictor_MC * moderator_MC.
   execute.

5. Run moderated multiple regression model

   REGRESSION
   /MISSING PAIRWISE
   /STATISTICS COEFF OUTS R ANOVA
   /CRITERIA=PIN(.05) POUT(.10)
   /NOORIGIN 
   /DEPENDENT outcome
   /METHOD=ENTER predictor_MC moderator_MC predictorXmoderator covariate1 covariate2.

6. Create plot of interaction

   • see McCabe et al. (2018) and following links:
     • https://github.com/connorjmccabe/InterActive
     • https://connorjmccabe.shinyapps.io/interactive/ (archived at https://perma.cc/93G6-ALDP)

5 Best Practices

• Use SPSS syntax files (.sps) for performing all commands, including importing data, computing variables, recoding variables, running analyses, etc. The benefit of using SPSS syntax files (and code-based files, more generally) is that they allow you to reproduce your findings again with the same data file. This is important so you do not have to remember all of the steps you followed to generate the analysis. This also allows you to quickly re-run the analysis if the data file is updated due to the collection of more data. If you are unsure what SPSS command is needed, run the command via “point and click” in the interface; however, instead of clicking “OK”, click “Paste”. This will paste the syntax that is used to run the command into a syntax file.
  • Have one syntax file for importing data, computing composites, recoding variables, and saving data (e.g., import.sps).
  • Have a separate syntax file for generating frequencies, descriptive statistics, and correlation matrices (e.g., descriptives.sps).
  • Have a separate syntax file for running analyses (e.g., analyses.sps).
  • Comment your syntax frequently
    • to comment use the following convention:
      • *type comment.
  • Save your syntax frequently

---

---